pano_interface_1.pro 3.16 KB
#--------------------------------------------------
# Panoramic is an interface for the visualization of panoramas capable of
# handling wide fields of view, based on Möbius transformations.
# Copyright (C) 2015 Luis Peñaranda, Luiz Velho and Leonardo Sacht.
# 
# This program is free software: you can redistribute it and/or modify it
# under the terms of the GNU General Public License as published by the
# Free Software Foundation, either version 3 of the License, or (at your
# option) any later version.
# 
# This program is distributed in the hope that it will be useful, but
# WITHOUT ANY WARRANTY; without even the implied warranty of
# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
# General Public License for more details.
# 
# You should have received a copy of the GNU General Public License along
# with this program.  If not, see <http://www.gnu.org/licenses/>.
#-------------------------------------------------- 

#-------------------------------------------------
#
# Project created by QtCreator 2012-06-06T09:22:08
#
#-------------------------------------------------

QT       += core gui opengl

# uncomment to show in the main window controls for other methods
DEFINES += PANO_EXTENDED_CONTROLS

# compiler specific settings
darwin-g++*|macx-g++*|linux-g++*|win32-g++*|cygwin-g++* {
QMAKE_CXXFLAGS += -ansi -pedantic -Wno-long-long
INCLUDEPATH += "C:/MinGW/include"
DEPENDPATH += "C:/MinGW/include"
INCLUDEPATH += "C:/Qt/4.8.4-mingw/include"
DEPENDPATH += "C:/Qt/4.8.4-mingw/include"
LIBS += -L"C:/MinGW/lib"
LIBS += -L"C:/MinGW/bin"
LIBS += -L"C:/Qt/4.8.4-mingw/lib"
LIBS += -L"C:/Qt/4.8.4-mingw/bin"
}

win32-msvc* {
DEFINES += _CRT_SECURE_NO_WARNINGS
LIBS += "/nodefaultlib:LIBCMT"
INCLUDEPATH += "C:/Qt/4.8.4/include"
DEPENDPATH += "C:/Qt/4.8.4/include"
LIBS += -L"C:/Qt/4.8.4/lib"
LIBS += -L"C:/Qt/4.8.4/bin"
}

mac {
LIBS += -L/opt/local/lib
LIBS += -lpng -ljpeg -lpnm
LIBS += -framework Carbon -framework OpenGL -framework GLUT
INCLUDEPATH += /opt/local/include/netpbm/ \
               /opt/local/include/
} else:unix {
#LIBS += -lm -lpng -lpetsc -lglut -lGL -lnetpbm
LIBS += -lm -lglut -lGL -lGLEW -ljpeg -lpng -lnetpbm
# GLee is required when the version of opengl is old
#SOURCES += GLee.c
#HEADERS += GLee.h
#DEFINES += NEEDGLEE
}

win32 {
DEFINES += GLEW_STATIC
PFROOT = "C:/Program Files"
INCLUDEPATH += $${PFROOT}/glew-1.9.0/include
DEPENDPATH += $${PFROOT}/glew-1.9.0/include
INCLUDEPATH += $${PFROOT}/freeglut/include
DEPENDPATH += $${PFROOT}/freeglut/include
INCLUDEPATH += $${PFROOT}/GnuWin32/include
DEPENDPATH += $${PFROOT}/GnuWin32/include
LIBS += -L$${PFROOT}/freeglut/lib
LIBS += -L$${PFROOT}/GnuWin32/lib
LIBS += -L$${PFROOT}/GnuWin32/bin
LIBS += -L$${PFROOT}/glew-1.9.0/lib
LIBS += -lglew32s -lfreeglut -lglu32 -lopengl32 -ljpeg -llibpng -llibnetpbm10
}

TARGET = pano_interface_1
TEMPLATE = app

SOURCES += main.cpp\
        panowindow1.cpp \
    openglcanvas.cpp \
    chronos.cpp \
    image_read.cpp

HEADERS  += panowindow1.h \
    openglcanvas.h \
    chronos.h \
    glincludes.h \
    image_read.h \
    files.h

FORMS    += panowindow1.ui \
    extended_controls.ui

OTHER_FILES += \
    shaders/fragment_shader.frag \
    shaders/vertex_shader.vert